またたきエフェクト

光が点滅しているようなエフェクトの作り方です
解説はつづきから

新規ファイル作成
ステージ設定はサイズを400×300、背景色を黒、フレームレートは30に

新規シンボル作成からActionScriptに書き出しにチェックを入れて、クラス名をBallに

20×20の円を描く
線なし、色は#FFFFFFから#CCCCCCの円形グラデーション

シーン1に戻りActionScript記述

var glow:GlowFilter;
var balls:Array = [];
var lightOn:Boolean = false;    //光が点いてるかどうか
var num:int = 100;    //ballの数

for (var i = 0; i<num; i++) {
    //ball作成
    var ball:Ball = new Ball();
    //ballの位置
    ball.x = Math.cos(i/20*Math.PI*2)*i*2+200;
    ball.y = Math.sin(i/26*Math.PI*2)*i*1.6+150;
    //ballの大きさ、透明度
    ball.scaleX = ball.scaleY = i/100+Math.random()*0.3;
    ball.alpha = 0.1;
    //ball配置、配列に格納
    addChild(ball);
    balls.push(ball);
}

//クリックイベント追加
stage.addEventListener(MouseEvent.CLICK, clickHandler);

function clickHandler(e:Event):void {
    //lightOnの切り替え
    lightOn = !lightOn;

    //lightOnがtrueのとき
    if (lightOn) {
        for (i = 0; i<num; i++) {
            var col = Math.random()*0xFFFFFF;
            //グローフィルタの設定(色,透明度,ぼかし水平,ぼかし垂直,強度,画質)
            glow = new GlowFilter(col,1,10,10,1.5,BitmapFilterQuality.MEDIUM);
            //フィルタ適用
            balls[i].filters = [glow];
        }
        //キラキラのイベント追加
        addEventListener(Event.ENTER_FRAME, glitter);

    //lightOnがfalseのとき
    } else {
        for (i = 0; i<num; i++) {
            //フィルタ無効化
            balls[i].filters = [];
            //透明度0.1に
            balls[i].alpha = 0.1;
        }
        //キラキライベント削除
        removeEventListener(Event.ENTER_FRAME, glitter);
    }
}

function glitter(e:Event):void {
    for (i = 0; i<num; i++) {
        //透明度をランダムに変化
        balls[i].alpha = 0.8+Math.random()*0.5;
    }
}

これでムービープレビューすると以下のようになってるかと思います

以上、またたきエフェクトの作り方でした